Modeling a system where you roll Xd20 and take highest, plus the second highest if the first one is a critical, etc

Question

I'm making my own combat/task resolution system (loosely based the advantage mechanic from D&D 5e). In this system a roll with "advantage" is resolved as follows:

1. Roll Xd20 and take the result of the highest rolled die.
2. If the highest roll is a "critical" (i.e. equal to or greater than a certain threshold, usually 20 but possibly 19 or even lower), add the result of the second highest roll.
3. If the second highest roll was also a critical, add the third highest roll, and so on, until you either get a non-critical result or run out of dice.
4. Finally, you add a modifier (based on your stats etc.) to the result.

Rolling with "disadvantage" works the same way, except that you start with the lowest roll and work upwards instead with criticals resulting from the low end of the dice.

1. Roll Xd20 and take the result of the lowest rolled die.
2. If the lowest roll is a "critical" (i.e. less than or equal to a certain threshold, usually 1 but possibly 2 or even higher), add the result of the second lowest roll.
3. If the second lowest roll was also a critical, add the third lowest roll, and so on, until you either get a non-critical result or run out of dice.
4. Finally, you add a modifier (based on your stats etc.) to the result.

---

Examples of rolls with advantage:

1. You roll 3d20 and score no critials → keep highest die, add modifier.

2. You roll 3d20 and score 1 critical → keep the sum of the two highest dice, add modifier.

3. You roll 3d20 and score 2 criticals → sum all three dice, add modifier.

---

I want to calculate the distribution of the results using this dice rolling mechanic to see what would be the effect of such changes compared to a simple "roll 2d20 keep highest" as in D&D 5e, but I'm having trouble doing so. This is how far I've gotten so far using AnyDice: https://anydice.com/program/2122a

Can anyone help me fix my program or otherwise model this dice rolling system?

Answer 1

Based on your clarifications (and assuming that you meant to count rolls equal to or below the threshold as crits when rolling with disadvantage, as described in your comment), these AnyDice functions should model your mechanic:

function: advantage ROLL:s crit CRIT:n {
  N: ROLL >= CRIT
  result: {1..1+N}@ROLL
}

function: disadvantage ROLL:s crit CRIT:n {
  N: ROLL <= CRIT
  result: {1..1+N}@[reverse ROLL]
}

You can use them like this:

output [advantage 3d20 crit 20] named "3d20 with advantage, crit on nat 20"
output [advantage 3d20 crit 19] named "3d20 with advantage, crit on nat 19-20"

output [disadvantage 3d20 crit 1] named "3d20 with disadvantage, crit on nat 1"
output [disadvantage 3d20 crit 2] named "3d20 with disadvantage, crit on nat 1-2"

Note that the way I've written the functions makes use of the fact that high rolls crit when rolling with advantage and low rolls crit when rolling with disadvantage. This means that your mechanics will always return the sum of all dice that roll a crit, plus the highest / lowest non-crit roll if there is any. So what the functions do is first count the number of crits N, and then return the sum of the N+1 highest (or lowest) of the rolled numbers.

The resulting distributions are… interesting:

Rolling with advantage using your system gives much more favorable results than using the D&D 5e "2d20 take highest" mechanic: not only is taking the highest of three dice much better than the highest of just two dice on its own, but your crit mechanic gives a non-trivial chance of getting results up to 40 (and a tiny but non-zero chance of rolling up to 60).

Meanwhile, your disadvantage rolls actually aren't that far off from D&D 5e disadvantage rolls, at least as far as the average result goes. While taking the lowest of 3d20 is less favorable than taking the lowest of 2d20, the crit mechanic compensates for this somewhat. Here the crits don't cause such wild explosions as they do when rolling with advantage, since each crit roll basically just adds 1 or 2 pips to the outcome instead of 19 or 20. Still, the shape of the distribution is quite different, generally favoring low rolls more heavily, but compensated by the impossibility(!) of rolling a 1 and the small but non-zero chance of rolling above 20.